总结:整理 oracle异常错误处理 . （转载）

5.1.1 预定义的异常处理

5.1.2 非预定义的异常处理

5.1.3 用户自定义的异常处理

5.1.4 用户定义的异常处理

5.2 异常错误传播

5.2.1 在执行部分引发异常错误

5.2.2 在声明部分引发异常错误

5.3 异常错误处理编程

5.4 在 PL/SQL 中使用 SQLCODE, SQLERRM异常处理函数

---

即使是写得最好的PL/SQL程序也会遇到错误或未预料到的事件。一个优秀的程序都应该能够正确处理各种出错情况，并尽可能从错误中恢复。任何ORACLE错误（报告为ORA-xxxxx形式的Oracle错误号）、PL/SQL运行错误或用户定义条件（不一写是错误），都可以。当然了，PL/SQL编译错误不能通过PL/SQL异常处理来处理，因为这些错误发生在PL/SQL程序执行之前。

ORACLE 提供异常情况(EXCEPTION)和异常处理(EXCEPTION HANDLER)来实现错误处理。

5.1 异常处理概念

异常情况处理(EXCEPTION)是用来处理正常执行过程中未预料的事件,程序块的异常处理预定义的错误和自定义错误,由于PL/SQL程序块一旦产生异常而没有指出如何处理时,程序就会自动终止整个程序运行.

有三种类型的异常错误：

    1． 预定义 ( Predefined )错误

  ORACLE预定义的异常情况大约有24个。对这种异常情况的处理，无需在程序中定义，由ORACLE自动将其引发。

    2． 非预定义 ( Predefined )错误

   即其他标准的ORACLE错误。对这种异常情况的处理，需要用户在程序中定义，然后由ORACLE自动将其引发。

    3． 用户定义(User_define) 错误

程序执行过程中，出现编程人员认为的非正常情况。对这种异常情况的处理，需要用户在程序中定义，然后显式地在程序中将其引发。

异常处理部分一般放在 PL/SQL 程序体的后半部,结构为:

EXCEPTION
   WHEN first_exception THEN 
   WHEN second_exception THEN 
   WHEN OTHERS THEN 
END;  

异常处理可以按任意次序排列,但 OTHERS 必须放在最后.

5.1.1 预定义的异常处理

   预定义说明的部分 ORACLE 异常错误

错误号	异常错误信息名称	说明
ORA-0001	Dup_val_on_index	违反了唯一性限制
ORA-0051	Timeout-on-resource	在等待资源时发生超时
ORA-0061	Transaction-backed-out	由于发生死锁事务被撤消
ORA-1001	Invalid-CURSOR	试图使用一个无效的游标
ORA-1012	Not-logged-on	没有连接到ORACLE
ORA-1017	Login-denied	无效的用户名/口令
ORA-1403	No_data_found	SELECT INTO没有找到数据
ORA-1422	Too_many_rows	SELECT INTO 返回多行
ORA-1476	Zero-divide	试图被零除
ORA-1722	Invalid-NUMBER	转换一个数字失败
ORA-6500	Storage-error	内存不够引发的内部错误
ORA-6501	Program-error	内部错误
ORA-6502	Value-error	转换或截断错误
ORA-6504	Rowtype-mismatch	宿主游标变量与 PL/SQL变量有不兼容行类型
ORA-6511	CURSOR-already-OPEN	试图打开一个已处于打开状态的游标
ORA-6530	Access-INTO-null	试图为null 对象的属性赋值
ORA-6531	Collection-is-null	试图将Exists 以外的集合( collection)方法应用于一个null pl/sql 表上或varray上
ORA-6532	Subscript-outside-limit	对嵌套或varray索引得引用超出声明范围以外
ORA-6533	Subscript-beyond-count	对嵌套或varray 索引得引用大于集合中元素的个数.

对这种异常情况的处理，只需在PL/SQL块的异常处理部分，直接引用相应的异常情况名，并对其完成相应的异常错误处理即可。

例1：更新指定员工工资，如工资小于1500，则加100；

 

DECLARE
   v_empno employees.employee_id%TYPE := &empno;
   v_sal   employees.salary%TYPE;
BEGIN
   SELECT salary INTO v_sal FROM employees WHERE employee_id = v_empno;
   IF v_sal<=1500 THEN
        UPDATE employees SET salary = salary + 100 WHERE employee_id=v_empno;
        DBMS_OUTPUT.PUT_LINE(‘编码为‘||v_empno||‘员工工资已更新!‘);    
   ELSE
        DBMS_OUTPUT.PUT_LINE(‘编码为‘||v_empno||‘员工工资已经超过规定值!‘);
   END IF;
EXCEPTION
   WHEN NO_DATA_FOUND THEN 
      DBMS_OUTPUT.PUT_LINE(‘数据库中没有编码为‘||v_empno||‘的员工‘);
   WHEN TOO_MANY_ROWS THEN
      DBMS_OUTPUT.PUT_LINE(‘程序运行错误!请使用游标‘);
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(SQLCODE||‘---‘||SQLERRM);
END;

 

5.1.2 非预定义的异常处理

对于这类异常情况的处理，首先必须对非定义的ORACLE错误进行定义。步骤如下：

1. 在PL/SQL 块的定义部分定义异常情况：

<异常情况>  EXCEPTION;

2. 将其定义好的异常情况，与标准的ORACLE错误联系起来，使用EXCEPTION_INIT语句：

PRAGMA EXCEPTION_INIT(<异常情况>, <错误代码>);

3. 在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

例2：删除指定部门的记录信息，以确保该部门没有员工。

INSERT INTO departments VALUES(50, ‘FINANCE‘, ‘CHICAGO‘);

DECLARE
   v_deptno departments.department_id%TYPE := &deptno;
   deptno_remaining EXCEPTION;
   PRAGMA EXCEPTION_INIT(deptno_remaining, -2292);
  
BEGIN
   DELETE FROM departments WHERE department_id = v_deptno;
EXCEPTION
   WHEN deptno_remaining THEN
      DBMS_OUTPUT.PUT_LINE(‘违反数据完整性约束!‘);
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(SQLCODE||‘---‘||SQLERRM);
END;  

5.1.3 用户自定义的异常处理

当与一个异常错误相关的错误出现时，就会隐含触发该异常错误。用户定义的异常错误是通过显式使用 RAISE 语句来触发。当引发一个异常错误时，控制就转向到 EXCEPTION块异常错误部分，执行错误处理代码。

对于这类异常情况的处理，步骤如下：

1． 在PL/SQL 块的定义部分定义异常情况：

<异常情况>  EXCEPTION;

2． RAISE <异常情况>；

3． 在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

例3：更新指定员工工资，增加100；

DECLARE
   v_empno employees.employee_id%TYPE :=&empno;
   no_result  EXCEPTION;
BEGIN
   UPDATE employees SET salary = salary+100 WHERE employee_id = v_empno;
   IF SQL%NOTFOUND THEN
      RAISE no_result;
   END IF;
EXCEPTION
   WHEN no_result THEN
      DBMS_OUTPUT.PUT_LINE(‘你的数据更新语句失败了!‘);
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(SQLCODE||‘---‘||SQLERRM);
END;  

5.1.4  用户定义的异常处理

调用DBMS_STANDARD(ORACLE提供的包)包所定义的RAISE_APPLICATION_ERROR过程，可以重新定义异常错误消息，它为应用程序提供了一种与ORACLE交互的方法。

RAISE_APPLICATION_ERROR 的语法如下：

    RAISE_APPLICATION_ERROR(error_number,error_message,[keep_errors] );

    这里的error_number 是从 –20,000 到 –20,999 之间的参数，

    error_message 是相应的提示信息(< 2048 字节)，

keep_errors 为可选，如果keep_errors =TRUE ,则新错误将被添加到已经引发的错误列表中。如果keep_errors=FALSE(缺省),则新错误将替换当前的错误列表。

例4：创建一个函数get_salary, 该函数检索指定部门的工资总和，其中定义了-20991和-20992号错误，分别处理参数为空和非法部门代码两种错误：

CREATE TABLE errlog(
  Errcode NUMBER,
  Errtext CHAR(40));

CREATE OR REPLACE FUNCTION get_salary(p_deptno NUMBER)
RETURN NUMBER
AS
  v_sal NUMBER;
BEGIN
  IF p_deptno IS NULL THEN
    RAISE_APPLICATION_ERROR(-20991, ’部门代码为空’);
  ELSIF p_deptno<0 THEN
    RAISE_APPLICATION_ERROR(-20992, ’无效的部门代码’);
  ELSE
    SELECT SUM(employees.salary) INTO v_sal FROM employees
    WHERE employees.department_id=p_deptno;
    RETURN v_sal;
  END IF;
END;

DECLARE
  V_salary NUMBER(7,2);
  V_sqlcode NUMBER;
  V_sqlerr VARCHAR2(512);
  Null_deptno EXCEPTION;
  Invalid_deptno EXCEPTION;
  PRAGMA EXCEPTION_INIT(null_deptno,-20991);
  PRAGMA EXCEPTION_INIT(invalid_deptno, -20992);
BEGIN
  V_salary :=get_salary(10);
  DBMS_OUTPUT.PUT_LINE(‘10号部门工资：‘ || TO_CHAR(V_salary));

  BEGIN
    V_salary :=get_salary(-10);
  EXCEPTION
    WHEN invalid_deptno THEN
      V_sqlcode :=SQLCODE;
      V_sqlerr  :=SQLERRM;
      INSERT INTO errlog(errcode, errtext)
      VALUES(v_sqlcode, v_sqlerr);
      COMMIT;
  END inner1;

  V_salary :=get_salary(20);
  DBMS_OUTPUT.PUT_LINE(‘部门号为20的工资为：‘||TO_CHAR(V_salary));

  BEGIN
    V_salary :=get_salary(NULL);
  END inner2;

  V_salary := get_salary(30);
  DBMS_OUTPUT.PUT_LINE(‘部门号为30的工资为：‘||TO_CHAR(V_salary));

  EXCEPTION
    WHEN null_deptno THEN
      V_sqlcode :=SQLCODE;
      V_sqlerr  :=SQLERRM;
      INSERT INTO errlog(errcode, errtext) VALUES(v_sqlcode, v_sqlerr);
      COMMIT;
    WHEN OTHERS THEN
         DBMS_OUTPUT.PUT_LINE(SQLCODE||‘---‘||SQLERRM);
END outer;  

例5：定义触发器，使用RAISE_APPLICATION_ERROR阻止没有员工姓名的新员式记录插入：

CREATE OR REPLACE TRIGGER tr_insert_emp
BEFORE INSERT ON employees
FOR EACH ROW
BEGIN
  IF :new.first_name IS NULL OR :new.last_name is null THEN
    RAISE_APPLICATION_ERROR(-20000,‘Employee must have a name.‘);
  END IF;
END;  

5.2 异常错误传播

    由于异常错误可以在声明部分和执行部分以及异常错误部分出现，因而在不同部分引发的异常错误也不一样。

5.2.1 在执行部分引发异常错误

    当一个异常错误在执行部分引发时，有下列情况：

l 如果当前块对该异常错误设置了处理，则执行它并成功完成该块的执行，然后控制转给包含块。

l 如果没有对当前块异常错误设置定义处理器，则通过在包含块中引发它来传播异常错误。然后对该包含块执行步骤1)。

5.2.2 在声明部分引发异常错误

    如果在声明部分引起异常情况，即在声明部分出现错误，那么该错误就能影响到其它的块。比如在有如下的PL/SQL程序：

DECLARE
    name varchar2(12):=‘EricHu‘;
    其它语句
BEGIN
    其它语句
EXCEPTION
    WHEN OTHERS THEN
    其它语句
END;  

     例子中，由于Abc number(3)=’abc’; 出错，尽管在EXCEPTION中说明了WHEN OTHERS THEN语句，但WHEN OTHERS THEN也不会被执行。 但是如果在该错误语句块的外部有一个异常错误，则该错误能被抓住，如：

BEGIN
    DECLARE
    name varchar2(12):=‘EricHu‘;
    其它语句
   BEGIN
    其它语句
   EXCEPTION
    WHEN OTHERS THEN
    其它语句
    END;
EXCEPTION
WHEN OTHERS THEN
    其它语句
END;  

5.3 异常错误处理编程

    在一般的应用处理中，建议程序人员要用异常处理，因为如果程序中不声明任何异常处理，则在程序运行出错时，程序就被终止，并且也不提示任何信息。下面是使用系统提供的异常来编程的例子。

5.4  在 PL/SQL 中使用 SQLCODE, SQLERRM异常处理函数

    由于ORACLE 的错信息最大长度是512字节，为了得到完整的错误提示信息，我们可用 SQLERRM和 SUBSTR 函数一起得到错误提示信息，方便进行错误，特别是如果WHEN OTHERS异常处理器时更为方便。

SQLCODE  返回遇到的Oracle错误号,

SQLERRM  返回遇到的Oracle错误信息.

如:  SQLCODE=-100   è SQLERRM=’no_data_found ‘

SQLCODE=0      è SQLERRM=’normal, successfual completion’

例6. 将ORACLE错误代码及其信息存入错误代码表

CREATE TABLE errors (errnum NUMBER(4), errmsg VARCHAR2(100));

DECLARE
   err_msg  VARCHAR2(100);
BEGIN
  
   FOR err_num IN -100 .. 0 LOOP
      err_msg := SQLERRM(err_num);
      INSERT INTO errors VALUES(err_num, err_msg);
   END LOOP;
END;
DROP TABLE errors;  

例7. 查询ORACLE错误代码；

BEGIN
   INSERT INTO employees(employee_id, first_name,last_name,hire_date,department_id)
   VALUES(2222, ‘Eric‘,‘Hu‘, SYSDATE, 20);
   DBMS_OUTPUT.PUT_LINE(‘插入数据记录成功!‘);
  
   INSERT INTO employees(employee_id, first_name,last_name,hire_date,department_id)
   VALUES(2222, ‘胡‘,‘勇‘, SYSDATE, 20);
   DBMS_OUTPUT.PUT_LINE(‘插入数据记录成功!‘);
EXCEPTION
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(SQLCODE||‘---‘||SQLERRM);
END;  

例8. 利用ORACLE错误代码，编写异常错误处理代码；

DECLARE
   empno_remaining EXCEPTION;
   PRAGMA EXCEPTION_INIT(empno_remaining, -1);
  
BEGIN
   INSERT INTO employees(employee_id, first_name,last_name,hire_date,department_id)
   VALUES(3333, ‘Eric‘,‘Hu‘, SYSDATE, 20);
   DBMS_OUTPUT.PUT_LINE(‘插入数据记录成功!‘);
  
   INSERT INTO employees(employee_id, first_name,last_name,hire_date,department_id)
   VALUES(3333, ‘胡‘,‘勇‘,SYSDATE, 20);
   DBMS_OUTPUT.PUT_LINE(‘插入数据记录成功!‘);
EXCEPTION
   WHEN empno_remaining THEN
      DBMS_OUTPUT.PUT_LINE(‘违反数据完整性约束!‘);
   WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(SQLCODE||‘---‘||SQLERRM);
END;    

1、异常的优点
　　
　　如果没有异常，在程序中，应当检查每个命令的成功还是失败，如
　　BEGIN
　　SELECT ...
　　-- check for ’no data found’ error
　　SELECT ...
　　-- check for ’no data found’ error
　　SELECT ...
　　-- check for ’no data found’ error
　　这种实现的方法缺点在于错误处理没有与正常处理分开，可读性差，使用异常，可以方便处理错误，而且异常处理程序与正常的事务逻辑分开，提高了可读性，如
　　BEGIN
　　SELECT ...
　　SELECT ...
　　SELECT ...
　　...
　　EXCEPTION
　　WHEN NO_DATA_FOUND THEN -- catches all ’no data found’ errors
　　
　　2、异常的分类
　　
　　有两种类型的异常，一种为内部异常，一种为用户自定义异常，内部异常是执行期间返回到PL/SQL块的ORACLE错误或由PL/SQL代码的某操作引起的错误，如除数为零或内存溢出的情况。用户自定义异常由开发者显示定义，在PL/SQL块中传递信息以控制对于应用的错误处理。
　　
　　每当PL/SQL违背了ORACLE原则或超越了系统依赖的原则就会隐式的产生内部异常。因为每个ORACLE错误都有一个号码并且在PL/SQL中异常通过名字处理，ORACLE提供了预定义的内部异常。如SELECT INTO 语句不返回行时产生的ORACLE异常NO_DATA_FOUND。对于预定义异常，现将最常用的异常列举如下：
　　exception　 oracle error　 sqlcode value　 condition
　　no_data_found　　　　　　　　　　　　　 ora-01403　 +100　 select into 语句没有符合条件的记录返回
　　too_many_rows　 ora-01422　 -1422　 select into 语句符合条件的记录有多条返回
　　dup_val_on_index　 ora-00001　 -1　 对于数据库表中的某一列，该列已经被限制为唯一索引，程序试图存储两个重复的值
　　value_error　 ora-06502　 -6502　 在转换字符类型，截取或长度受限时，会发生该异常，如一个字符分配给一个变量，而该变量声明的长度比该字符短，就会引发该异常
　　storage_error　 ora-06500　 -6500　 内存溢出
　　zero_divide　 ora-01476　 -1476　 除数为零
　　case_not_found　 ora-06592　 -6530　 对于选择case语句，没有与之相匹配的条件，同时，也没有else语句捕获其他的条件
　　cursor_already_open　 ora-06511　 -6511　 程序试图打开一个已经打开的游标
　　timeout_on_resource　 ora-00051　 -51　 系统在等待某一资源，时间超时
　　
　　如果要处理未命名的内部异常，必须使用OTHERS异常处理器或PRAGMA EXCEPTION_INIT 。PRAGMA由编译器控制，或者是对于编译器的注释。PRAGMA在编译时处理，而不是在运行时处理。EXCEPTION_INIT告诉编译器将异常名与ORACLE错误码结合起来，这样可以通过名字引用任意的内部异常，并且可以通过名字为异常编写一适当的异常处理器。
　　
　　在子程序中使用EXCEPTION_INIT的语法如下：
　　PRAGMA EXCEPTION_INIT(exception_name, -Oracle_error_number);
　　
　　在该语法中，异常名是声明的异常，下例是其用法：
　　DECLARE
　　deadlock_detected EXCEPTION;
　　PRAGMA EXCEPTION_INIT(deadlock_detected, -60);
　　BEGIN
　　... -- Some operation that causes an ORA-00060 error
　　EXCEPTION
　　WHEN deadlock_detected THEN
　　-- handle the error
　　END;
　　
　　对于用户自定义异常，只能在PL/SQL块中的声明部分声明异常，异常的名字由EXCEPTION关键字引入：
　　reserved_loaned Exception
　　
　　产生异常后，控制传给了子程序的异常部分，将异常转向各自异常控制块，必须在代码中使用如下的结构处理错误：
　　Exception
　　When exception1 then
　　Sequence of statements;
　　When exception2 then
　　Sequence of statements;
　　When others then
　　
　　3、异常的抛出
　　
　　由三种方式抛出异常
　　
　　1． 通过PL/SQL运行时引擎
　　
　　2. 使用RAISE语句
　　
　　3. 调用RAISE_APPLICATION_ERROR存储过程
　　
　　当数据库或PL/SQL在运行时发生错误时，一个异常被PL/SQL运行时引擎自动抛出。异常也可以通过RAISE语句抛出
　　RAISE exception_name;
　　
　　显式抛出异常是程序员处理声明的异常的习惯用法，但RAISE不限于声明了的异常，它可以抛出任何任何异常。例如，你希望用TIMEOUT_ON_RESOURCE错误检测新的运行时异常处理器，你只需简单的在程序中使用下面的语句：
　　RAISE TIMEOUT_ON_RESOUCE;
　　
　　比如下面一个订单输入的例子，若当订单小于库存数量，则抛出异常，并且捕获该异常，处理异常
　　DECLARE
　　inventory_too_low EXCEPTION;
　　
　　---其他声明语句
　　BEGIN
　　IF order_rec.qty>inventory_rec.qty THEN
　　RAISE inventory_too_low;
　　END IF
　　EXCEPTION
　　WHEN inventory_too_low THEN
　　order_rec.staus:=‘backordered‘;
　　END;
　　
　　RAISE_APPLICATION_ERROR内建函数用于抛出一个异常并给异常赋予一个错误号以及错误信息。自定义异常的缺省错误号是+1,缺省信息是User_Defined_Exception。RAISE_APPLICATION_ERROR函数能够在pl/sql程序块的执行部分和异常部分调用，显式抛出带特殊错误号的命名异常。　 Raise_application_error(error_number,message[,true,false]))
　　
　　错误号的范围是-20,000到-20,999。错误信息是文本字符串，最多为2048字节。TRUE和FALSE表示是添加(TRUE)进错误堆(ERROR STACK)还是覆盖(overwrite)错误堆(FALSE)。缺省情况下是FALSE。
　　
　　如下代码所示：
　　IF product_not_found THEN
　　RAISE_APPLICATION_ERROR(-20123,‘Invald product code‘ TRUE);
　　END IF;
　　
　　4、异常的处理
　　
　　PL/SQL程序块的异常部分包含了程序处理错误的代码，当异常被抛出时，一个异常陷阱就自动发生，程序控制离开执行部分转入异常部分,一旦程序进入异常部分就不能再回到同一块的执行部分。下面是异常部分的一般语法：
　　EXCEPTION
　　WHEN exception_name THEN
　　Code for handing exception_name
　　[WHEN another_exception THEN
　　Code for handing another_exception]
　　[WHEN others THEN
　　code for handing any other exception.]
　　
　　用户必须在独立的WHEN子串中为每个异常设计异常处理代码，WHEN OTHERS子串必须放置在最后面作为缺省处理器处理没有显式处理的异常。当异常发生时，控制转到异常部分，ORACLE查找当前异常相应的WHEN..THEN语句，捕捉异常，THEN之后的代码被执行，如果错误陷阱代码只是退出相应的嵌套块，那么程序将继续执行内部块END后面的语句。如果没有找到相应的异常陷阱，那么将执行WHEN OTHERS。在异常部分WHEN 子串没有数量限制。
　　EXCEPTION
　　WHEN inventory_too_low THEN
　　order_rec.staus:=‘backordered‘;
　　replenish_inventory(inventory_nbr=>
　　inventory_rec.sku,min_amount=>order_rec.qty-inventory_rec.qty);
　　WHEN discontinued_item THEN
　　--code for discontinued_item processing
　　WHEN zero_divide THEN
　　--code for zero_divide
　　WHEN OTHERS THEN
　　--code for any other exception
　　END;
　　
　　当异常抛出后，控制无条件转到异常部分，这就意味着控制不能回到异常发生的位置，当异常被处理和解决后，控制返回到上一层执行部分的下一条语句。
　　BEGIN
　　DECLARE
　　bad_credit exception;
　　BEGIN
　　RAISE bad_credit;
　　--发生异常，控制转向；
　　EXCEPTION
　　WHEN bad_credit THEN
　　dbms_output.put_line(‘bad_credit‘);
　　END;
　　--bad_credit异常处理后，控制转到这里
　　EXCEPTION
　　WHEN OTHERS THEN
　　
　　--控制不会从bad_credit异常转到这里
　　
　　--因为bad_credit已被处理
　　
　　END;
　　
　　当异常发生时，在块的内部没有该异常处理器时，控制将转到或传播到上一层块的异常处理部分。
　　
　　BEGIN
　　DECLARE ---内部块开始
　　
　　bad_credit exception;
　　BEGIN
　　RAISE bad_credit;
　　
　　--发生异常，控制转向；
　　EXCEPTION
　　WHEN ZERO_DIVIDE THEN --不能处理bad_credite异常
　　dbms_output.put_line(‘divide by zero error‘);
　　
　　END --结束内部块
　　
　　--控制不能到达这里，因为异常没有解决；
　　
　　--异常部分
　　
　　EXCEPTION
　　WHEN OTHERS THEN
　　--由于bad_credit没有解决，控制将转到这里
　　END;
　　
　　5、异常的传播
　　
　　没有处理的异常将沿检测异常调用程序传播到外面，当异常被处理并解决或到达程序最外层传播停止。在声明部分抛出的异常将控制转到上一层的异常部分。
　　
　　BEGIN
　　executable statements
　　BEGIN
　　today DATE:=‘SYADATE‘; --ERRROR
　　
　　BEGIN --内部块开始
　　dbms_output.put_line(‘this line will not execute‘);
　　EXCEPTION
　　WHEN OTHERS THEN
　　
　　--异常不会在这里处理
　　
　　END;--内部块结束
　　EXCEPTION
　　WHEN OTHERS THEN
　　
　　处理异常
　　
　　END

 

-------------------------------------------------------------------------------------------------------------------------
-------------------------------------------------------------------------------------------------------------------------

 

处理 oracle 系统自动生成系统异常外，可以使用 raise 来手动生成错误。

l         Raise exception;

l         Raise package.exception;

l         Raise;

以上是 raise 的三种使用方法。第一种用于生成当前程序中定义的异常或在 standard 中的系统异常。

       Declare

              Invalid_id exception;

              Id_values varchar(2);

       Begin

              Id_value:=id_for(‘smith’);

              If substr(id_value,1,1)!=’x’

              Then

                     Raise invalid_id;

              End if;

       Exception

              When invalid_id

              Then

                     Dbms_output.put_line(‘this is an invalid id!’);

       End;

这是一个生成自定义异常的例子，当然也可以生成系统异常：

       declare

              employee_id_in number;

       Begin

Select employee_id into employee_id_in from employ_list where employee_name=&n;

If employee_id_in=0

Then

       Raise zero_devided;

End if;

       Exception

              When zero_devided

              Then

                     Dbms_output.put_line(‘wrong!’);

       End;

有一些异常是定义在非标准包中的，如 UTL_FILE ， DBMS_SQL 以及程序员创建的包中异常。可以使用 raise 的第二种用法来生成异常。

       If day_overdue(isbn_in, browser_in) > 365

       Then

              Raise overdue_pkg.book_is_lost

       End if;

在最后一种 raise 的形式中，不带任何参数。这种情况只出现在希望将当前的异常传到外部程序时。

       Exception

              When no_data_found

              Then

                     Raise;

       End;

Pl.sql 使用 raise_application_error 过程来生成一个有具体描述的异常。当使用这个过程时，当前程序被中止，输入输出参数被置为原先的值，但任何 DML 对数据库所做的改动将被保留，可以在之后用 rollback 命令回滚。下面是该过程的原型：

       Procedure raise_application_error(

       Num binary_integer;

       Msg varchar2;

       Keeperrorstack Boolean default false

)

其中 num 是在 -20999 到 -20000 之间的任何数字（但事实上， DBMS_OUPUT 和 DBMS_DESCRIBLE 包使用了 -20005 到 -20000 的数字）； msg 是小于 2K 个字符的描述语，任何大于 2K 的字符都将被自动丢弃； keeperrorstack 默认为 false ，是指清空异常栈，再将当前异常入栈，如果指定 true 的话就直接将当前异常压入栈中。

    CREATE OR REPLACE PROCEDURE raise_by_language (code_in IN PLS_INTEGER)

    IS

       l_message error_table.error_string%TYPE;

    BEGIN

       SELECT error_string

         INTO l_message

         FROM error_table, v$nls_parameters v

        WHERE error_number = code_in

          AND string_language = v.VALUE

          AND v.parameter = ‘NLS_LANGUAGE‘;

       RAISE_APPLICATION_ERROR (code_in, l_message);

    END;

 

 

ORACL内部异常：

 

１：预定义异常 

用于处理常见的Oracle错误 

２：非预定义异常 

用于处理预定义异常所不能处理的Oracle错误 

３：自定义异常 

用于处理于Oracle错误无关的其他情况 

异常处理部分是以关键字EXCEPTION开始的，语法如下： 

  EXCEPTION 

    WHEN  exception_Name THEN  --exception_Name为异常的名字 

      statement1; 

    WHEN OTHERS THEN 

  statement1; 

异常处理部分从关键字EXCEPTION开始，在异常处理部分使用WHEN字句捕捉各种异常，如果有其他未预定义到的异常，使用WHEN OTHERS THEN字句进行捕捉和处理。 

• 1、 处理预定义异常，这是系统预定的21种类型 
•   错误代码是负整数，如-51 
•       
•  
•     
•   Access_info_null（ora-06530） 
•      当访问没有初始化的对象时触发。 
•     
•   Case_not_found(ora-06592) 
•      case过程中when后没有包含必要的条件分支并且没有else子句，则会触发本异常。 
•     
•   Collection_is_null(06531) 
• 访问未初始化的集合元素（嵌套表或者varray）。
•     
•   Cursor_already_open(ora-06511) 
•      重新打开已经打开的游标。 
•     
•   Dup_val_on_index(ora-00001) 
•      当中唯一索引所对应的列上键入重复值时。 
•     
•   Invalid_cursor(ora-01001) 
• 试图在不合法的游标上执行操作时，譬如没打开游标就提取内容
•     
•   Invalid_number(ora-01722) 
•      当试图将非法的字符串转换为数字类型时。 
•     
•   No_data_found(ora-01403) 
•      执行select into未返回行，或者引用了索引表未初始化的元素时。 
•     
•   Too_many_rows(ora-01422) 
•      执行select into返回超过一行数据时。 
•     
•   Zero_divide(ora-01476) 
•      0作为被除数时。 
•     
•   Subscript_beyond_count(ora-06533) 
•      使用嵌套表或者varray集合时，如果引用下标超过last。 
•     
• Subscript_outside_limit(ora-06532)
•      使用嵌套表或varray集合时，如果引用下标小于first。 
•     
•   Value_error(ora-06502) 
•      在执行赋值操作时，如果变量长度不足以容纳实际数据。 
•     
•   Login_denied(ora-01017) 
•      连接数据库时提供了不正确的用户名或口令。 
•     
•   Not_logged_on(ora-01012) 
• 在程序没有连接到oracle数据库时执行plsql代码则会触发。
•     
•   Program_error(ora-06501) 
•      plsql内部问题。 
•     
•   Rowtype_mismatch(ora-06504) 
•      执行赋值操作时，如果宿主游标变量和PLSQL游标变量返回类型不兼容时。 
•     
•   Self_is_null(ora-30625) 
•      使用对象类型时，如果在null实例上调用成员方法。 
•     
•   Storage_error(ora-06500) 
•      超出内存空间或者内存被损坏。 
•     
•   Sys_invalid_rowid（ora-01410） 
•      无效字符串企图转换为rowid类型时。 
•     
•   Timeout_on_resource(ora-00051) 
•      等待资源时出现超时错误。 
•     
•  
•  
• 2、处理非预定义异常 
• 使用非预定义异常包括三步： 
• 一：在定义部分定义异常名， 
• 二：在异常和Oracle错误之间建立关联， 
• 三：在异常处理部分捕捉并处理异常。 
•  
•  
• 当定义Oracle错误和异常之间的关联关系时，需要使用伪过程EXCEPTION_INIT。 
•  
•  
• 一：首先的定义部分定义异常； 
• 二：使用progmaexception_init(exception_name,exception_number) 在异常和oracle错误之间建立关联， 
•     这时要求用户知道可能出现的错误号（异常函数sqlcode、sqlerrm和raise_application_error）； 
• 三：最终在异常处理部分捕捉并处理异常。 
•  
•   
•  
•  
• 下面以更新特定雇员的部门号，并处理ORA-02291错误为例，说明使用非预定义异常的方法。示例如下： 
•  
•  
•   DECLARE 
•     e_integrity EXCEPTION;  --1、定义部分 
•     PRAGMA EXCEPTION_INIT (e_integrity, -2291);  --2、建立关联关系 
•   BEGIN 
•     UPDATE  emp SET deptno=  &dno WHERE  empno = &eno; 
•   EXCEPTION 
•     WHEN  e_integrity THEN  --3、捕捉处理 
•       DBMS_OUTPUT.PUT_LINE(‘该部门不存在’); 
•   END; 
•    
•  
•     
• --3、处理自定义异常 
• 预定义异常和非预定义异常都与Oracle错误有关，并且当出现Oracle错误时会隐含触发相应异常； 
• 而自定义异常与Oracle错误没有任何关联，它是由开发人员为特定情况所定义的异常。 
•  
•  
• 当使用自定义异常时， 
• 一：需要在定义部分（DECLARE）定义异常， 
• 二：再执行部分（BEGIN）触发异常（使用RAISE语句）， 
• 三：在异常处理部分（EXCEPTION）捕捉并处理异常。 
•  
•  
•   declare 
•    myexception exception; 
•   begin 
•    
• if 
• 1=0 
• then 
•    
• raise myexception; 
•    
• endif;  
•   exception 
•    
• when 
•  
• myexception  
• then 
•        dbms_output.put_line(‘asdf‘); 
•   end; 
•     
• 注意：不能在同一个block中描述EXCEPTION两次，但是可以描述一个exception在两个不同的block中。异常（exception）是有作用域的，子块的异常不能被当前块所捕捉， 
•  
•   
•  
• --４、使用异常函数： 
• Oracle内置函数sqlcode和sqlerrm主要用在others处理器中，分别用来返回oracle的错误代码和错误消息。 
• 一般情况下sqlcode返回负数标识的oracle错误代码，除非错误 
• 为‘ora-01403：no data found’，此时对应的sqlcode为+100， 
• 对于用户自定义的异常，sqlcode返回+1，如果没有异常被触发，sqlcode返回0。 
•   Begin 
•   Exception 
•    When  others then 
•       Dbms_output.put_line(sqlcode||sqlerrm(sqlcode)); 
•   End; 
•     
•  
•   
•  
•  
• Oracle过程raise_application_error用于在plsql应用程序中自定义错误消息。 
• 注意该过程只能在数据库端的子程序（过程、函数、包、触发器）中使用，而不能在匿名块和客户端的子程序中使用。 
• 语法为raise_application_error(error_number,message[,[true|false]]); 
• 其中 
•  
• error_number用于定义错误号，该错误号必须在-20000到-20999之间的负整数； 
• message用于指定错误消息，并且该消息的长度不 
• 能超过2048字节； 
• 第三个参数如果为true，则该错误会被放在先前错误堆栈中，如果为false（默认值）则会替代先前所有错误。 
•   IF product_not_found THEN 
•                RAISE_APPLICATION_ERROR(-20123,‘Invald product code‘  TRUE); 
•   END IF; 
•     
•  
•   
•  
•  
• --５、plsql编译警告： 
• plsql警告可以分为四类： 
• severe：用于 
• 检查可能出现的不可预料或者错误结果，例如参数的别名问题； 
• performance：用于检查可能引起的性能问题，例如执行insert操作时为 number列提供了varchar2类型数据； 
• informational：用于检查子程序中的死代码； 
• all：用于检查所有警告。 
•  
•  
• 为了数据库可以在编 
• 译plsql子程序时发出警告信息，需要设置初始化参数plsql_warnings。这个参数不仅可以在系统级或者会话级设置，也可以在alter procedure命令中设置。 
•   Alter {system|session|procedure}  
•   set plsql_warnings= 
•    
• ’{enable|disable:{all |performance|severe|informational}}’; 
•     
•  
•  
• 为了检查是否存在对应警告信息，必须先激活警告检查，然后重新编译子程序， 
• 最后使用show errors命令显示警告错误。 
•   create or  replace procedure  my_test 
•   is 
•   begin 
•    if  1=0 then 
•       dbms_output.put_line(‘test‘); 
•    endif;  
•   end; 
•   SQL>  alter procedure  my_test compile plsql_warnings = ‘enable:all‘; 
•    
•  
•   Procedure altered 
•    SQL>  show errors; 
•   Errors for  PROCEDURE SYS.MY_TEST: 
•    LINE/COL ERROR 
•   --------  ------------------------- 
•   10/5      PLW-06002: 无法执行的代码 
•     
•  
•  
• --6、定义Exception时要注意的一些事项 
• 当异常发生时，在块的内部没有该异常处理器时，控制将转到或传播到上一层块的异常处理部分。 
• 没有处理的异常将沿检测异常调用程序传播到外层，当异常被处理并解决或到达程序最外层传播停止。在声明部分抛出的异常将控制转到上一层的异常部分。 
•  
•  
• 用户必须在独立的WHEN子串中为每个异常设计异常处理代码，WHEN OTHERS子串必须放置在最后面作为缺省处理器处理没有显式处理的异常。当异常发生时，控制转到异常部分，ORACLE查找当前异常相应的WHEN..THEN语句，捕捉异常，THEN之后的代码被执行，如果错误陷阱代码只是退出相应的嵌套块，那么程序将继续执行内部块END后面的语句。如果没有找到相应的异常陷阱，那么将执行WHEN OTHERS。在异常部分WHEN 子串没有数量限制。 
•   EXCEPTION 
•    
• WHEN inventory_too_low THEN 
•    
•       ...... 
•    
• WHEN discontinued_item THEN 
•    
•       ...... 
•    
• WHEN zero_divide THEN 
•    
•       ...... 
•    
• WHEN OTHERS THEN 
•    
•       ......  
•  
•  
• oracle预定义的异常列表 
• 2008-10-30 16:06 
• 命名的系统异常         产生原因  
• ACCESS_INTO_NULL         未定义对象  
• CASE_NOT_FOUND         CASE 中若未包含相应的 WHEN ，并且没有设置 ELSE 时  
• COLLECTION_IS_NULL         集合元素未初始化  
• CURSER_ALREADY_OPEN         游标已经打开  
• DUP_VAL_ON_INDEX         唯一索引对应的列上有重复的值  
• INVALID_CURSOR         在不合法的游标上进行操作  
• INVALID_NUMBER         内嵌的 SQL 语句不能将字符转换为数字  
• NO_DATA_FOUND         使用 select into 未返回行，或应用索引表未初始化的元素时  
• TOO_MANY_ROWS         执行 select into 时，结果集超过一行  
• ZERO_DIVIDE         除数为 0  
• SUBSCRIPT_BEYOND_COUNT         元素下标超过嵌套表或 VARRAY 的最大值  
• SUBSCRIPT_OUTSIDE_LIMIT         使用嵌套表或 VARRAY 时，将下标指定为负数  
• VALUE_ERROR         赋值时，变量长度不足以容纳实际数据  
• LOGIN_DENIED         PL/SQL 应用程序连接到 oracle 数据库时，提供了不正确的用户名或密码  
• NOT_LOGGED_ON         PL/SQL 应用程序在没有连接 oralce 数据库的情况下访问数据  
• PROGRAM_ERROR         PL/SQL 内部问题，可能需要重装数据字典＆ pl./SQL 系统包  
• ROWTYPE_MISMATCH         宿主游标变量与 PL/SQL 游标变量的返回类型不兼容  
• SELF_IS_NULL         使用对象类型时，在 null 对象上调用对象方法  
• STORAGE_ERROR         运行 PL/SQL 时，超出内存空间  
• SYS_INVALID_ID         无效的 ROWID 字符串  
• TIMEOUT_ON_RESOURCE         Oracle 在等待资源时超时 
•  
• ============================================================= 
•  
• BEGIN 
• 《PL/SQL块》; 
• Exception 
• when no_data_found then --没有找到数据 
• 《响应命令》; 
• when too_many_rows then --返回多行，隐式光标每次只能检索一行数据 
• 《响应命令》; 
• when invalid_number then --字符向数字转换失败 
• 《响应命令》; 
• when zero_divide then --被零除 
• 《响应命令》; 
• when dup_val_on_index then --向唯一索引中插入重复数据 
• 《响应命令》; 
• when invalid_cursor then --非法游标操作 
• 《响应命令》; 
• when value_error then --数字的,数据转换,截字符串或强制性的错误 
• 《响应命令》; 
• when others then --发生其它任何错误 
• null; --选择一：什么也不做，就当错误没发生 
• raise form_trigger_failure; --选择二：挂起当前程序 
• END; 
•  
•  
• 常用预定义例外 
• EXCEPTION 
• WHEN CURSOR_ALREADY_OPEN THEN -- ORA-06511 SQLCODE = -6511 游标已经打开 
• ..WHEN DUP_VAL_ON_INDEX THEN -- ORA-00001 SQLCODE = -1 向唯一索引中插入重复数据 
• ..WHEN INVALID_CURSOR THEN -- ORA-01001 SQLCODE = -1001 非法游标操作 
• ..WHEN INVALID_NUMBER THEN -- ORA-01722 SQLCODE = -1722 字符向数字转换失败 
• ..WHEN LOGIN_DENIED THEN -- ORA-01017 SQLCODE = -1017  
•  
• ..WHEN NO_DATA_FOUND THEN -- ORA-01403 SQLCODE = +100 没有找到数据 
• ..WHEN NOT_LOGGED_ON THEN -- ORA-01012 SQLCODE = -1012  
• ..WHEN PROGRAM_ERROR THEN -- ORA-06501 SQLCODE = -6501 程序错误 
• ..WHEN STORAGE_ERROR THEN -- ORA-06500 SQLCODE = -6500 
• ..WHEN TIMEOUT_ON_RESOURCE THEN -- ORA-00051 SQLCODE = -51 
•  
• ..WHEN TOO_MANY_ROWS THEN -- ORA-01422 SQLCODE = -1422 返回多行 
• ..WHEN TRANSACTION_BACKED_OUT THEN -- ORA-00061 SQLCODE = -61 
•  
• ..WHEN VALUE_ERROR THEN -- ORA-06502 SQLCODE = -6502 数值转换错误 
• ..WHEN ZERO_DIVIDE THEN -- ORA-01476 SQLCODE = -1476 被零除 
• ..WHEN OTHERS THEN